Rules for integrands of the form(((a+b x))^m)

1.  ∫(x^m)dx

1:  ∫(1/x)dx

Reference: G&R 2.01.2, CRC 9, A&S 3.3.15

Derivation: Reciprocal rule for integration

Rule 1.1.1.1.1.1:

∫(1/x)dx  ⟶  Log[x]

Program code:

Int[1/x_,x_Symbol] :=
  Log[x]

2:  ∫(x^m)dx  when  m≠-1

Reference: G&R 2.01.1, CRC 7, A&S 3.3.14

Derivation: Power rule for integration

Rule 1.1.1.1.1.2: If  m≠-1, then

∫(x^m)dx  ⟶  ((x^(m+1))/(m+1))

Program code:

Int[x_^m_.,x_Symbol] :=
  x^(m+1)/(m+1) /;
FreeQ[m,x] && NeQ[m,-1]

2.  ∫(((a+b x))^m)dx

1:  ∫(1/(a+b x))dx

Reference: G&R 2.111.1.2, CRC 27, A&S 3.3.15

Derivation: Reciprocal rule for integration

Rule 1.1.1.1.2.1:

∫(1/(a+b x))dx  ⟶  ((Log[a+b x])/b)

Program code:

Int[1/(a_+b_.*x_),x_Symbol] :=
  Log[RemoveContent[a+b*x,x]]/b /;
FreeQ[{a,b},x]

2:  ∫(((a+b x))^m)dx  when  m≠-1

Reference: G&R 2.111.1.1, CRC 23, A&S 3.3.14

Derivation: Power rule for integration

Rule 1.1.1.1.2.2: If  m≠-1, then

∫(((a+b x))^m)dx  ⟶  ((((a+b x))^(m+1))/(b (m+1)))

Program code:

Int[(a_.+b_.*x_)^m_,x_Symbol] :=
  (a+b*x)^(m+1)/(b*(m+1)) /;
FreeQ[{a,b,m},x] && NeQ[m,-1]

S:  ∫(((a+b u))^m)dx  when  u==c+d x

Derivation: Integration by substitution

Rule 1.1.1.1.S: If  u==c+d x, then

∫(((a+b u))^m)dx  ⟶  (1/d)Subst[∫(((a+b x))^m)dx,x,u]

Program code:

Int[(a_.+b_.*u_)^m_,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(a+b*x)^m,x],x,u] /;
FreeQ[{a,b,m},x] && LinearQ[u,x] && NeQ[u,x]